Actualités
12/08/22 La jungle des utilitaires d'appairage sans fil chez Razer
11/08/22 Layer Shift pour rajouter des boutons à la souris Glorious Model I
10/08/22 Logitech met à jour les applications Options et Options+
04/08/22 Le pilote AMD Software 22.7.1 supporte Windows 11 22H2 et Noise Suppression
29/07/22 G HUB 2022.7 pour les périphériques Logitech Aurora Collection et appairage LIGHTSPEED multiple
28/07/22 Les drivers 3Dconnexion 3DxWare 10.8.8 compatibles Windows 11
28/07/22 CORSAIR iCUE 4.25/4.26 : K70 PRO MINI, HS55/HS65 WIRELESS, VENGEANCE RGB DDR5, NVIDIA Broadcast...
20/07/22 NVIDIA corrige plusieurs bugs dans les jeux avec le hotfix GeForce 516.79
12/07/22 Correctif antirebond pour les claviers mécaniques Glorious GMMK Pro et GMMK 2
08/07/22 Drivers NVIDIA 473.73 pour le GPU GeForce GTX 1630 et Windows 7


Fichiers
12/08/22 Hercules DJ Console/DJ Control 2.HDJS.2022
11/08/22 Razer USB HyperSpeed Dongle Utility 1.00.01 R1
11/08/22 Razer Barracuda 1.04.00 R1
11/08/22 Razer Barracuda Pro 1.04.01 R1
11/08/22 Razer Headset Pairing Utility 1.00.00 R5
11/08/22 Pioneer DJ XDJ-RX3 1.13
11/08/22 Pioneer BDR-XD07B/CB/S/TB/TS 1.04
11/08/22 Pioneer BDR-XD07TUHD/UHD 1.04
11/08/22 HAVIT Magic Eagle HV-MS920 Programmable Gaming Mouse 1.0
11/08/22 Hercules DJUCED 5.0 5.3.5
Accueil / Problèmes avec les drivers, bios et firmwares
Répondre Actualiser Rechercher S'inscrire ou s'identifier FAQ

Pages : 1

Par michel_91
Le 03/02/2016 à 10:11:05



Inscription : le 03/07/2004
Supprimer périphériques obsolètes    Modifier le message
Bonjour,
J'ai changé il y a peut de temps ma carte mère et le processeur de mon PC.
Hier par curiosité je suis allée regarder dans le gestionnaire de périphériques et affichage des périphériques cachés et j'ai vu que de nombreux matériels obsolètes étaient encore installés, dont l'ancien processeur et plein d'autres choses encore.
Comment supprimer les périphériques obsolètes?
Manuellement me parait fastidieux.
merci
Par PIERRE02
Le 03/02/2016 à 11:11:18

Inscription : le 08/02/2012
Supprimer périphériques obsolètes    Modifier le message   Configuration de PIERRE02
Pour cela :

1 - Trouver la version de devcon.exe qui correspond à votre système d' exploitation

2 - Faire un fichier que vous lancerez en mode administrateur avec par exemple ce nom: remove.bat et le contenu suivant:

--------------------- supprimer cette ligne -----------------------------
@ECHO OFF
:: Check DOS/Windows version
IF NOT "%OS%"=="Windows_NT" GOTO Syntax

:: Localize variables
SETLOCAL

:: Check command line arguments
IF NOT "%~1"=="" IF /I NOT "%~1"=="/D" IF /I NOT "%~1"=="/Y" GOTO Syntax

:: Check if debug mode is requested
IF /I NOT "%Debug%"=="ECHO" SET Debug=
ECHO.%* | FIND /I "/D" >NUL && SET Debug=ECHO

:: Check if confirmation is required
SET Confirmed=N
ECHO.%* | FIND /I "/Y" >NUL && SET Confirmed=Y

:: Check if DEVCON.EXE is available and if not, prompt for download
SET DevconAvailable=
SET Download=
DEVCON.EXE /? >NUL 2>&1
IF ERRORLEVEL 1 (
SET DevconAvailable=No
ECHO This batch file requires Microsoft's DEVCON untility.
SET /P Download=Do you want to download it now? [y/N]
)

:: Start download if requested
IF /I "%Download%"=="Y" (
START "DevCon" "http://support.microsoft.com/default.aspx?scid=kb;EN-US;Q311272"
ECHO.
ECHO Install the downloaded file and make sure DEVCON.EXE is in the PATH.
ECHO Then try again.
)

:: Abort if DEVCON.EXE is not available yet
IF "%DevconAvailable%"=="No" GOTO End

:: Ask for confirmation, unless overruled by command line switch
IF NOT "%Confirmed%"=="Y" (
ECHO You are about to remove all inactive PnP devices from this computer.
SET /P Confirmed=Are you sure you want to continue? [yN]
)
IF /I NOT "%Confirmed%"=="Y" GOTO Syntax

:: Save a list of all active devices in a temporary file
DEVCON Find * | FIND /I /V "matching device(s)" > "%Temp%\DevconFind.txt"
IF NOT EXIST "%Temp%\DevconFind.txt" GOTO Syntax

:: List all devices, both hidden/inactive and active ones, and remove
:: all devices that are not listed as active in the temporary file
FOR /F "tokens=1 delims=: " %%A IN ('DEVCON FindAll * ^| FIND /I /V "matching device(s)"';) DO (
TYPE "%Temp%\DevconFind.txt" | FIND "%%~A" >NUL
IF ERRORLEVEL 1 %Debug% DEVCON Remove "@%%~A"
)

:: Remove the temporary file
DEL "%Temp%\DevconFind.txt"

:: Done
ENDLOCAL
GOTO:EOF


:Syntax
ECHO.
ECHO RmHidDev.bat, Version 1.00 for Windows 2000 / XP
ECHO Use DEVCON to remove all hidden/inactive PnP devices.
ECHO.
ECHO Usage: RMHIDDEV [ /D ] [ /Y ]
ECHO.
ECHO Where: /D Will only ECHO the removal commands instead of executing them
ECHO /Y Will remove devices without confirmation
ECHO.
ECHO Notes: [1] This batch file requires Microsoft's DEVCON.EXE, available at
ECHO http://support.microsoft.com/default.aspx?scid=kb;EN-US;Q311272
ECHO You will be prompted for download if it isn't found.
ECHO [2] This batch file was developed with "ghost devices" on Ghost images
ECHO in mind. It has been tested on Windows XP Ghost images only.
ECHO I cannot guarantee flawless operation on any other PC.
ECHO Use this batch file entirely at your own risk. Make sure you have
ECHO a recent full backup available in case something might go wrong.
ECHO And remember to test, test, test and test before using it in a
ECHO production environment.
ECHO.
ECHO Written by Rob van der Woude
ECHO http://www.robvanderwoude.com

IF "%OS%"=="Windows_NT" ENDLOCAL
Par michel_91
Le 03/02/2016 à 17:11:02



Inscription : le 03/07/2004
Supprimer périphériques obsolètes    Modifier le message
Je suis sous windows 10 64 bits et l'exe devcon je ne le trouve pas. j'ai créé un fichier remove .bat avec le bloc note de toutes les lignes de code proposé.
maintenant comment je fais?
Faut-il exécuter exe et ensuite le bat?
merci beaucoup.
Par PIERRE02
Le 03/02/2016 à 20:36:59

Inscription : le 08/02/2012
Supprimer périphériques obsolètes    Modifier le message   Configuration de PIERRE02
Vous trouverez "devcon.exe" ici :

https://msdn.microsoft.com/en-us/library/windows/hardware/ff544707(v=vs.85).aspx
Par michel_91
Le 04/02/2016 à 10:55:28



Inscription : le 03/07/2004
Supprimer périphériques obsolètes    Modifier le message
merci, je vais me débrouiller avec ça!
Par michel_91
Le 05/02/2016 à 11:15:26



Inscription : le 03/07/2004
Supprimer périphériques obsolètes    Modifier le message
En faite le devcon fait parti d"un kit de développement si j'ai bien compris et fait la bagatelle 1,7 Go.
Par PIERRE02
Le 05/02/2016 à 18:07:56

Inscription : le 08/02/2012
Supprimer périphériques obsolètes    Modifier le message   Configuration de PIERRE02
J'ai déjà trouvé quelque fois sur internet mais pas vu ces temps-ci

Il faut donc télécharger le kit , installer ou extraire les fichiers du kit , récupérer les deux versions 32 et 64 bits et les sauvegarder quelque part pour le futur ...
Pages : 1


Retour sur le forum Problèmes avec les drivers, bios et firmwares

Identification

Nom d'utilisateur
Mot de passe

  Recevez vos identifiants par e-mail si vous les avez oubliés.
  Inscrivez-vous si vous n'êtes pas encore membre de TousLesDrivers.com.
 
Répondre au message Supprimer périphériques obsolètes

   Message
      

   Insérer des smileys
    :)  ;)  :D  :P  :(  :?:
    Plus de smileys
    Lien N°1 / Lien N°2 / Puce / Gras / Italique / Souligné / Barré

   Merci de lire la FAQ avant d'ajouter un message.